; What v0.32
;
; Simple query script, some might even call it a lame infobot :)
; Basically it saves what people add/remove in What.dat in your mIRC
; directory and brings it back out again on request, might make a nice
; addon for a mIRC bot. The floodprotection is simple, only five actions
; are allowed per minute - after the five actions are used up you'll have
; to wait for the minute to timeout, then ask again. 
;
; Commands:
;
; !What, !Add, !Rem - Query, Add, Remove
;
; And of course, the required variables:
;
; %WHAT_AdminChannels - channels where there is NO floodprotection, everyone can use !add, !del and !what
; %WHAT_Channels - channels where there IS floodprotection, everyone can use !what, !add and !del usage is based on settings
; %WHAT_Add - allow people in %WHAT_Channels to use !add? (1 = Yes)
; %WHAT_Rem - allow people in %WHAT_Channels to use !del? (1 = Yes)
;
; Todo (aka. Bugs):
; Flood protection (works), user system for adding removing (?) (we got the AdminChannels), restrict channels(got that too, Channels) - it's done done done!
;
; - Faile
;

ON *:CONNECT:{ UNSET %WHAT_Flood }

ON *:TEXT:!Add*:#:{
  IF ((($CHAN ISIN %WHAT_Channels) && (%WHAT_Add == 1) && (%WHAT_Flood <= 5) && ($3)) || (($CHAN ISIN %WHAT_AdminChannels) && ($3))) {
    IF (%WHAT_Flood == $NULL) { INC -u60 %WHAT_Flood } | ELSE { INC %WHAT_Flood }

    WRITE -s $+ $2 What.dat $REPLACE($2-,|,$!CHR(124)) | MSG $CHAN Added.
  }
}

ON *:TEXT:!Rem*:#:{
  IF ((($CHAN ISIN %WHAT_Channels) && (%WHAT_Rem == 1) && (%WHAT_Flood <= 5) && ($2)) || (($CHAN ISIN %WHAT_AdminChannels) && ($2))) {
    IF (%WHAT_Flood == $NULL) { INC -u60 %WHAT_Flood } | ELSE { INC %WHAT_Flood }

    IF ($READ(What.dat,s, $2 ) == $NULL) { MSG $CHAN What...? }
    ELSE { WRITE -ds $+ $2 What.dat | MSG $CHAN Removed. }
  }
}

ON *:TEXT:!What*:#:{
  IF ((($CHAN ISIN %WHAT_Channels) && (%WHAT_Flood <= 5) && ($2)) || (($CHAN ISIN %WHAT_AdminChannels) && ($2))) {
    IF (%WHAT_Flood == $NULL) { INC -u60 %WHAT_Flood } | ELSE { INC %WHAT_Flood }

    IF ($READ(What.dat,s, $2 ) != $NULL) { MSG $CHAN $2 is $READ(What.dat,s, $2 ) }
    ELSE { MSG $CHAN What...? }
  }
}