;
; skin.mrc
;
;  An example of how you can change the layout of everything.
;
; --
; Faile
;

on ^*:action:*:#:{ haltdef
  if ($nick isop $chan) { echo $color(action) -m $chan $timestamp /@ $+ $nick - action/ $1- }
  elseif ($nick isvo $chan) { echo $color(action) -m $chan $timestamp /+ $+ $nick - action/ $1- }
  else { echo $color(action) -m $chan $timestamp / $+ $nick - action/ $1- }
}

on ^*:action:*:?:{ haltdef
  echo $color(action) -m $nick $timestamp / $+ $nick - action/ $1-
}

on *:input:*:{ if ($ctrlenter) || ($left($1,1) == $readini(mirc.ini,text,commandchar)) { return } | haltdef
  echo $color(own text) -am $timestamp / $+ $me $+ / $1-
  .msg $active $1-
}

on ^*:join:#:{ haltdef
  echo $color(join) $chan $timestamp --> $nick ( $+ $fulladdress $+ )
}

on ^*:rawmode:#:{ haltdef
  echo $color(mode) $chan $timestamp *** $nick $1-
}

on ^*:nick:{ haltdef
  var %i = 1
  while (%i <= $comchan($newnick,0)) {
    echo $color(nick) $comchan($newnick,%i) $timestamp $nick --> $newnick
    inc %i
  }
}

on ^*:part:#:{ haltdef
  echo $color(part) $chan $timestamp <-- part <-- $nick ( $+ $fulladdress -- $1- $+ )
}

on ^*:quit:{ haltdef
  var %i = 1
  while (%i <= $comchan($nick,0)) {
    echo $color(quit) -m $comchan($nick,%i) $timestamp <-- quit <-- $nick ( $+ $fulladdress -- $1- $+ )
    inc %i
  }
}

on ^*:text:*:#:{ haltdef
  if ($nick isop $chan) { echo $color(text) -m $chan $timestamp /@ $+ $nick $+ / $1- }
  elseif ($nick isvo $chan) { echo $color(text) -m $chan $timestamp /+ $+ $nick $+ / $1- }
  else { echo $color(text) -m $chan $timestamp / $+ $nick $+ / $1- }
}

on ^*:text:*:?:{ haltdef
  echo $color(text) -m $nick $timestamp / $+ $nick $+ / $1-
}