;
; Leech v0.14a
;
; I've made this script solely for my own purposes and uses, by no means do I promise that it
; works flawlessly or that it even works at all. You're using this script at your own risk, even
; if it could end up burning down your house and killing your family.
;
; Installing the script is simple, copy Leech.mrc and Leech.txt (this file) to your mIRC
; directory (c:\mIRC) and type "/load -rs Leech.mrc" in mIRC. It will automatically install
; itself and be ready for use.
;
; When you feel you want to test the script type /leech and a little dialogbox will ask you if
; you'd like to leech, answer yes and you're off. The first step is to join all the channels
; defined in %Leech_Channels and then open two new windows in mIRC, one called Leech and the
; other one Notice. The script will also start to monitor all the channels you're on looking for
; XDCC advertisements and if/when it finds one it will copy the relevant information to the
; Leech window showing the filename and download command (try to doubleclick on the "/msg" word).
; Any notices you recieve will also be displayed in the Notice window.
;
; That's about it, just a few points left to mention.
;
; * The recommended net for this script is EFnet, since it hosts a lot of good XDCC's
;
; * Any ad displayed in Leech will automatically be ignored for the next two hours
;
; * All ads are logged to Leech.log and Mini-Leech.log
;
; * You can change the channels, ignoretime and leech logo if you know a little bit about
;   scripting or are good with computers (press alt+r in mIRC and go to the variables tab)
;
; * Dont ask me any questions about all this, if there's something you dont understand ask a
;   friend and if he doesnt understand ask somebody else - just dont ask me
;
; * Dont expect too much of life, it doesnt expect much of you
;
; --
; Faile
;

ALIAS Leech {
  IF ($SERVER == $NULL) {
    ECHO -a %LeechLogo You must be connected to a server before Leeching!
  }
  ELSEIF (%Leech == 0) {
    IF ($$?!="Leech?" == $TRUE) {
      .ENABLE #Leech
      JOIN %LeechChannels
      SET %Leech 1
      WINDOW -ek[0] @Leech
      WINDOW -ek[0] @Notice
    }
  }
  ELSE {
    IF ($$?!="Are you sure you want to stop Leeching?" == $TRUE) {
      .DISABLE #Leech
      SET %Leech 0
    }
  }
}

MENU @Leech {
  Leech
  .$iif($server == $null,$style(2)) $iif(%Leech == 1,$style(2)) Start:IF ($$?!="Leech?" == $TRUE) { .ENABLE #Leech | JOIN %LeechChannels | SET %Leech 1 | WINDOW -ek[0] @Notice }
  .$iif($server == $null,$style(2)) $iif(%Leech == 0,$style(2)) Stop:IF ($$?!="Are you sure you want to stop Leeching?" == $TRUE) { .DISABLE #Leech | SET %Leech 0 }
  -
  Logs
  .Leech.log:run notepad.exe leech.log
  .Mini-Leech.log:run notepad.exe mini-leech.log
}

ON *:CONNECT:{
  ECHO -s %LeechLogo Leech v0.14a
  ECHO -s %LeechLogo
  ECHO -s %LeechLogo Loading...
  ECHO -s %LeechLogo ...removing temporary variables
  UNSET %Leech_*
  ECHO -s %LeechLogo ...verifying script integrity
  ; ...sometime
  ECHO -s %LeechLogo ...done!
  ECHO -s %LeechLogo
  ECHO -s %LeechLogo Type /leech to Leech!
}

ON *:LOAD:{
  SET %Leech 0
  SET %LeechBlockSeconds 7200
  SET %LeechChannels #IMP-ISO,#ALBUMS,#PUREISO,#ISOURCE,#ISOPARADISE,#WAREZ_R_US
  SET %LeechLogo [ Leech ]

  ECHO -s %LeechLogo Leech v0.14a
  ECHO -s %LeechLogo
  ECHO -s %LeechLogo Installing...
  ECHO -s %LeechLogo ...required variables
  ECHO -s %LeechLogo ...done!
  ECHO -s %LeechLogo
  ECHO -s %LeechLogo Type /leech to Leech!
}

ON *:UNLOAD:{
  ECHO -s %LeechLogo Leech v0.14a
  ECHO -s %LeechLogo
  ECHO -s %LeechLogo Uninstalling...
  ECHO -s %LeechLogo ...required variables
  ECHO -s %LeechLogo ...temporary variables
  ECHO -s %LeechLogo ...done!
  ECHO -s %LeechLogo
  ECHO -s %LeechLogo Thank you for using Leech!

  UNSET %Leech
  UNSET %LeechBlockSeconds
  UNSET %LeechChannels
  UNSET %LeechLogo
  UNSET %Leech_*
}

#Leech off

ON *:DISCONNECT:{ .DISABLE #Leech | SET %Leech 0 }

ON *:ERROR:*:{ .DISABLE #Leech | SET %Leech 0 }

ON *:EXIT:{ .DISABLE #Leech | SET %Leech 0 }

ON *:NOTICE:*:?:{ ECHO -mt @Notice < $+ $NICK $+ > $1- }

ON ^*:HOTLINK:/MSG:@Leech:{}

ON *:HOTLINK:/MSG:@Leech:{ IF ($?!="Would you like to download this file?" == $TRUE) { $GETTOK($HOTLINE,2,47) } }

ON *:TEXT:*:#:{
  IF (($CHR(35) ISIN $1) && (%Leech_ [ $+ [ $NICK ] $+ [ $REMOVE($DELTOK($1-,2,32),$CHR(32)) ] ] == $NULL)) {
    SET -u $+ [ %LeechBlockSeconds ] %Leech_ $+ $NICK $+ $REMOVE($DELTOK($1-,2,32),$CHR(32)) 1
    ;ECHO -t @Leech * 9Debug: Blocking $NICK on $CHAN $+ ! ( $+ $1- $+ )

    ECHO -mt @Leech *
    ECHO -t @Leech * File:
    ECHO -t @Leech * 12 $1-
    ECHO -t @Leech *
    ECHO -t @Leech * Download:
    ECHO -t @Leech * 4 /MSG $NICK XDCC SEND $REMOVE($1,$CHR(40),$CHR(41),$CHR(91),$CHR(93))
    ECHO -t @Leech *

    WRITE Leech.log * 
    WRITE Leech.log * [[ $NICK / $CHAN / $TIME / $DATE ]]
    WRITE Leech.log *
    WRITE Leech.log * File:
    WRITE Leech.log *  $1-
    WRITE Leech.log *
    WRITE Leech.log * Download:
    WRITE Leech.log *  /MSG $NICK XDCC SEND $REMOVE($1,$CHR(40),$CHR(41),$CHR(91),$CHR(93))
    WRITE Leech.log *

    WRITE Mini-Leech.log * $1-
  }
  ;ELSEIF (%Leech_ [ $+ [ $NICK ] $+ [ $REMOVE($DELTOK($1-,2,32),$CHR(32)) ] ] != $NULL) { ECHO -t @Leech * 3Debug: Blocked $NICK on $CHAN $+ ! ( $+ $1- $+ ) }
}

#Leech end